Attached is a beta ScriptBasic 2.2 release for Windows. (IUP included)  The only installation step is to adjust your PATH variable to point to the bin directory of this beta. I have included a test directory with examples and their output. (.out) Some of the extension module like MySQL and cURL require their runtime libraries/clients installed before using the ScriptBasic extension modules for them. I have uploaded a zip of extension module support DLLs that should go in your system32 on XP and SysWOW64 on 64 bit Windows 7.

Note: There are two version of the ScriptBasic interpreter. For console applications and redirection (stdin/out) use scriba.exe. If you wish to run GUI based applications, use the Windows sbiup.exe version of the interpreter that has no console support. If you like you could associate the .sbx attribute for example to sbiup.exe which would allow you to run the script directly by clicking on them in explorer or as a shortcut.

Feedback welcome.

ScriptBasic Documentation

ScriptBasic Forum




SBx_buttons
' SBx_buttons Example

INCLUDE "SBx"

SUB Btn1_clicked
  PRINT "BUTTON 1 Event\n"
END SUB

SUB Btn2_clicked
  PRINT "BUTTON 2 Event\n"
END SUB

SUB Btn3_clicked
  PRINT "BUTTON 3 Event\n"
END SUB

SUB Win_exit
  Iup::ExitLoop = TRUE
END SUB


win = WINDOW()
SETPROPERTY(win, "TITLE=\"SBx Buttons\", SIZE=300x")
horzbox = HBOX()
SETPROPERTY(horzbox, "GAP=5")
btn1 = BUTTON()
SETPROPERTY(btn1, "TITLE=Button1, EXPAND=HORIZONTAL")
btn2 = BUTTON()
SETPROPERTY(btn2, "TITLE=Button2, EXPAND=HORIZONTAL")
btn3 = BUTTON()
SETPROPERTY(btn3, "TITLE=Button3, EXPAND=HORIZONTAL")
APPEND(horzbox, btn1)
APPEND(horzbox, btn2)
APPEND(horzbox, btn3)
APPEND(win, horzbox)
EVENT(win,"CLOSE_CB",ADDRESS(Win_exit()))
EVENT(btn1,"ACTION",ADDRESS(Btn1_clicked()))
EVENT(btn2,"ACTION",ADDRESS(Btn2_clicked()))
EVENT(btn3,"ACTION",ADDRESS(Btn3_clicked()))
SHOW(win)



sbiupdict.sb
IMPORT iup.bas

servers[0]="dict.org"
servers[1]="dict1.us.dict.org"
servers[2]="all.dict.org"

about="""This is a Demo
of the IUP GUI Binding
for Scriptbasic"""

' Initialize IUP
Iup::Open()

' Create main window

win = Iup::Create("dialog")
  Iup::SetAttributes(win, "TITLE=\"ScriptBasic IUP Online Dictionary\", SIZE=500x300")
  Iup::SetCallback(win,"CLOSE_CB",ADDRESS(Win_exit()))

' Create container to house ALL GUI objects

vbox = Iup::Create("vbox")
  Iup::SetAttributes(vbox, "MARGIN=10x10")

' Create server panel

topBox = Iup::Create("hbox")
  Iup::SetAttributes(topBox, "GAP=10")
  Iup::Append(vbox, topBox)
serverFrame = Iup::Create("frame")
  Iup::SetAttributes(serverFrame, "TITLE=Servers, EXPAND=YES")
  Iup::Append(topBox, serverFrame)
serverBox = Iup::Create("hbox")
  Iup::SetAttributes(serverBox, "GAP=5")
  Iup::Append(serverFrame, serverBox)
serverCombo = Iup::Create("list")
  Iup::SetAttributes(serverCombo, "DROPDOWN=YES, SIZE=120x, EXPAND=HORIZONTAL, VALUE=1")
  Iup::Append(serverBox, serverCombo)
  Iup::SetCallback(serverCombo, "ACTION", ADDRESS(serverCombo_selected()))
btnFetch = Iup::Create("button")
  Iup::SetAttributes(btnFetch, "TITLE=Fetch, SIZE = 50x")
  Iup::Append(serverBox, btnFetch)
  Iup::SetCallback(btnFetch, "ACTION", ADDRESS(btnFetch_clicked()))

' Create control panel

controlFrame = Iup::Create("frame")
  Iup::SetAttributes(controlFrame, "TITLE=Controls")
  Iup::Append(topBox, controlFrame)
controlBox = Iup::Create("hbox")
  Iup::SetAttributes(controlBox, "GAP=5")
  Iup::Append(controlFrame, controlBox)
btnAbout = Iup::Create("button")
  Iup::SetAttributes(btnAbout, "TITLE=About, SIZE = 50x")
  Iup::Append(controlBox, btnAbout)
  Iup::SetCallback(btnAbout, "ACTION", ADDRESS(btnAbout_clicked()))
btnClear = Iup::Create("button")
  Iup::SetAttributes(btnClear, "TITLE=Clear, SIZE = 50x")
  Iup::Append(controlBox, btnClear)
  Iup::SetCallback(btnClear, "ACTION", ADDRESS(btnClear_clicked()))
btnExit = Iup::Create("button")
  Iup::SetAttributes(btnExit, "TITLE=Exit, SIZE = 50x")
  Iup::Append(controlBox, btnExit)
  Iup::SetCallback(btnExit,"ACTION",ADDRESS(Win_exit()))

' Create dictionary panel

dictFrame = Iup::Create("frame")
  Iup::SetAttributes(dictFrame, "TITLE=Dictionaries")
  Iup::Append(vbox, dictFrame)
serverList = Iup::Create("list")
  Iup::SetAttributes(serverList, "EXPAND=YES, VISIBLELINES=1")
  Iup::Append(dictFrame, serverList)
  Iup::SetCallback(serverList, "ACTION", ADDRESS(serverList_selected()))

' Create text part

transFrame = IUP::Create("frame")
  Iup::SetAttributes(transFrame, "TITLE=Translation")
  Iup::Append(vbox, transFrame)
text = Iup::Create("text")
  Iup::SetAttributes(text, "MULTILINE=YES, EXPAND=YES")
  Iup::Append(transFrame, text)

' Create entry and search button

bottomBox = Iup::Create("hbox")
  Iup::SetAttributes(bottomBox, "GAP=10")
  Iup::Append(vbox, bottomBox)
label = Iup::Create("label")
  Iup::SetAttributes(label, "TITLE=\"Enter Word to Search For:\", SIZE=x12")
  Iup::Append(bottomBox, label)
entry = Iup::Create("text")
  Iup::SetAttributes(entry, "EXPAND=HORIZONTAL")
  Iup::Append(bottomBox, entry)
btnSearch = Iup::Create("button")
  Iup::SetAttributes(btnSearch,"TITLE=Search, SIZE=50x")
  Iup::Append(bottomBox, btnSearch)
  Iup::SetCallback(btnSearch, "ACTION", ADDRESS(btnSearch_clicked()))
chkAll = Iup::Create("toggle")
  Iup::SetAttributes(chkAll, "TITLE=ALL, SIZE=x12")
  Iup::Append(bottomBox, chkAll)
chkUTF = Iup::Create("toggle")
  Iup::SetAttributes(chkUTF, "TITLE=UTF-8, SIZE=x12")
  Iup::Append(bottomBox, chkUTF)

' Add the main GUI container to the Window

Iup::Append(win, vbox)

' Setup dialog defaults

Iup::Show(win)
Iup::SetFocus(btnFetch)
FOR i = 0 TO UBOUND(servers)
  Iup::SetAttribute(serverCombo, "APPENDITEM", servers[i])
NEXT
Iup::SetAttribute(serverCombo, "VALUE", "1")
Iup::Update(serverCombo)
server_selection = servers[0]

' Main processing loop

Iup::MainLoop()
Iup::Close()
END

' Callback routines

SUB Win_exit
  Iup::ExitLoop = TRUE
END SUB

SUB btnAbout_clicked
  Iup::Message("ABOUT", about)
END SUB

SUB serverCombo_selected
  server_selection = Iup::GetListText()
END SUB

SUB serverList_selected
  whichDictionary = Iup::GetListText()
END SUB

SUB btnFetch_clicked
  LOCAL dat, total, count
  ON ERROR GOTO G_NetError
  OPEN server_selection & ":2628" FOR SOCKET AS #1
  PRINT#1,"SHOW DB\n"
  LINE INPUT#1, dat
  LINE INPUT#1, dat
  count = 0
  WHILE LEFT(dat, 1) <> "."
    LINE INPUT#1, dat
    IF LEFT(dat, 1) <> "." THEN total[count] = TRIM(dat)
    count+=1
  WEND
  PRINT#1,"QUIT\n"
  CLOSE(#1)
  FOR cnt = 0 TO count - 2
    Iup::SetAttribute(serverList, "APPENDITEM", total[cnt])
  NEXT
  Iup::SetAttribute(serverList, "VALUE", "1")
  Iup::Update(serverCombo)
  whichDictionary = total[0]
  EXIT SUB

  G_NetError:
  PRINT "Server ",server_selection," not available. (",ERROR,")\n"
END SUB

SUB btnClear_clicked
  Iup::ClearList(serverList)
  Iup::SetAttribute(text, "VALUE", "")
  Iup::SetAttribute(entry, "VALUE", "")
END SUB

SUB btnSearch_clicked
  LOCAL dict, dat, total, info
  IUP::SetAttribute(text, "VALUE","Fetching....")
  ON ERROR GOTO L_NetError
  dict = LEFT(whichDictionary, INSTR(whichDictionary, " "))
  OPEN server_selection & ":2628" FOR SOCKET AS 1
  IF Iup::GetAttribute(chkAll, "VALUE") THEN
    PRINT#1,"DEFINE * " & Iup::GetAttribute(entry,"VALUE") & "\n"
  ELSE
    PRINT#1,"DEFINE " & dict & " " & Iup::GetAttribute(entry,"VALUE") & "\n"
  END IF
  REPEAT
    LINE INPUT#1, dat
    IF LEFT(dat, 3) = "151" THEN
      total$ &= "------------------------------\r\n"
      total$ &= RIGHT(dat, LEN(dat) - LEN(Iup::GetAttribute(entry, "VALUE")) - LEN(dict))
      total$ &= "------------------------------\r\n"
      REPEAT
        LINE INPUT#1, info
        info = REPLACE(info, CHR(34), CHR(92) & CHR(34))
        IF LEFT(info, 1) <> "." THEN total &= TRIM(info) & "\n"
      UNTIL LEFT(info, 1) = "."
      total &= "\n"
    END IF
  UNTIL LEFT(dat, 3) = "250" OR VAL(LEFT(dat, 3)) > 499
  PRINT#1,"QUIT\n"
  CLOSE(#1)
  IF LEFT(dat, 3) = "552" THEN
    total = "No match found."
  ELSE IF LEFT(dat, 3) = "501" THEN
    total = "Select a dictionary first!"
  ELSE IF LEFT(dat, 3) = "550" THEN
    total = "Invalid database!"
  END IF
  Iup::SetAttribute(text, "VALUE", total)
EXIT SUB

L_NetError:
  dat[0] = "Could not lookup word! (" & ERROR & ")"
  Iup::SetAttribute(text, "VALUE", dat)
END SUB

testsqlite3.sb
import sqlite.bas

db = sqlite::open("sqlite3.db")

sqlite::execute(db,"create table demo (someval integer, sometxt text);")
sqlite::execute(db,"insert into demo values (123,'hello');")
sqlite::execute(db, "INSERT INTO demo VALUES (234, 'cruel');")
sqlite::execute(db, "INSERT INTO demo VALUES (345, 'world');")

stmt = sqlite::query(db,"SELECT * FROM demo")

while (sqlite::row(stmt) = sqlite::SQLITE3_ROW)
  if sqlite::fetchhash(stmt,column) then
    print column{"someval"},"\t-\t",column{"sometxt"},"\n"
  end if
wend

sqlite::close(db)

123   -   hello
234   -   cruel
345   -   world

testmysql.sb
' MySQL Test Program

INCLUDE mysql.bas

dbh = mysql::RealConnect("localhost","root","your_password","test")

mysql::query(dbh,"SELECT * FROM city LIMIT 0,10")

WHILE mysql::FetchHash(dbh,column)

PRINT "| "
PRINT column{"ID"}," | "
PRINT column{"Name"}," | "
PRINT column{"CountryCode"}," | "
PRINT column{"District"}," | "
PRINT column{"Population"}," |"
PRINTNL

WEND

PRINTNL
PRINT "The database handle is: ",dbh,"\n"
PRINT "Affected rows by SELECT: ",mysql::AffectedRows(dbh),"\n"
PRINT "Character set name is: ",mysql::CharacterSetName(dbh),"\n"
PRINT "Last error is: ",mysql::ErrorMessage(dbh),"\n"
PRINT "Client info is: ",mysql::GetClientInfo(),"\n"
PRINT "Host info is: ",mysql::GetHostInfo(dbh),"\n"
PRINT "Proto info is: ",mysql::GetProtoInfo(dbh),"\n"
PRINT "Server info is: ",mysql::GetServerInfo(dbh),"\n"
PRINT "PING result: ",mysql::Ping(dbh),"\n"
PRINT "Thread ID: ",mysql::ThreadId(dbh),"\n"
PRINT "Status is: ",mysql::Stat(dbh),"\n"

mysql::Close(dbh)

| 1 | Kabul | AFG | Kabol | 1780000 |
| 2 | Qandahar | AFG | Qandahar | 237500 |
| 3 | Herat | AFG | Herat | 186800 |
| 4 | Mazar-e-Sharif | AFG | Balkh | 127800 |
| 5 | Amsterdam | NLD | Noord-Holland | 731200 |
| 6 | Rotterdam | NLD | Zuid-Holland | 593321 |
| 7 | Haag | NLD | Zuid-Holland | 440900 |
| 8 | Utrecht | NLD | Utrecht | 234323 |
| 9 | Eindhoven | NLD | Noord-Brabant | 201843 |
| 10 | Tilburg | NLD | Noord-Brabant | 193238 |

The database handle is: 1
Affected rows by SELECT: 10
Character set name is: latin1
Last error is:
Client info is: 6.0.0
Host info is: localhost via TCP/IP
Proto info is: 10
Server info is: 5.5.28
PING result: -1
Thread ID: 0
Status is: Uptime: 23820  Threads: 1  Questions: 4  Slow queries: 0  Opens: 35  Flush tables: 1  Open tables: 1  Queries per second avg: 0.000

testodbc.sb
IMPORT odbc.bas

dbh = odbc::RealConnect("SBSQL3","","")

odbc::query(dbh,"SELECT * FROM demo")

WHILE odbc::FetchHash(dbh,dbcol)
  PRINT dbcol{"someval"},"\t-\t",dbcol{"sometxt"},"\n"
WEND

odbc::Close(dbh)

123   -   hello
234   -   cruel
345   -   world

testmxml.sb
import mxml.bas

filename = "stuff.xml"

doc = mxml::LoadDoc(filename)

node =  mxml::GetNode(doc,"/stufflist/stuff_test")
if node then print "Test1: ", mxml::GetNodeValue(node),"\n"

node =  mxml::GetNode(doc,"/stufflist/stuff_test2")
if (node) then print "Test2: ", mxml::GetNodeValue(node),"\n\n"
  
node = mxml::GetNode(doc,"/stufflist/stuff_test3/painting/img")
if node then
print "Image: ", mxml::GetProperty(node,"src"), "\n"
print "Alt Image: ", mxml::GetProperty(node,"alt"), "\n\n"
endif

node = mxml::GetNode(doc,"/stufflist/books")
child = mxml::GetChild(node)

while child
node = mxml::GetNode(child,"id")
if node then print "ID = ", mxml::GetNodeValue(node),"\n"
node = mxml::GetNode(child,"name")
if node then print "Name = ", mxml::GetNodeValue(node),"\n"

child = mxml::GetNext(child)
wend

if doc then mxml::FreeDoc(doc)

stuff.xml
<?xml version="1.0" encoding="UTF-8" ?>


<stufflist>
<stuff_test>This is a test!</stuff_test>
<stuff_test2>And this is another test!</stuff_test2>
<stuff_test3>
<painting>
<img src="madonna.jpg" alt='Foligno Madonna, by Raphael'/>
<caption>This is Raphael's "Foligno" Madonna, painted in
<date>1511</date>.
</caption>
</painting>
</stuff_test3>
<books>
    <book>
        <id>1</id>
        <name>Hello, world!</name>
    </book>
    <book>
        <id>2</id>
        <name>Hello, China!</name>
    </book>
</books>
</stufflist>

Test1: This is a test!
Test2: And this is another test!

Image: madonna.jpg
Alt Image: Foligno Madonna, by Raphael

ID = 1
Name = Hello, world!
ID = 2
Name = Hello, China!

testcurl.sb
INCLUDE curl.bas

ch = curl::init()
curl::option(ch,"URL","http://localhost/index.html")
' curl::option(ch,"FILE","test.html")
wp = curl::perform(ch)
' curl::perform(ch)
curl::finish(ch)

PRINT wp

<html><body><h1>It works!</h1></body></html>

ScriptBasic CGI response to a thinBasic QOD (Question of the Day) on operator precedence.

Which of the expressions will provide a different answer?

qod1.cgi
#! /usr/bin/scriba -c
INCLUDE cgi.bas
cgi::Header(200, "text/html")
cgi::FinishHeader()
 
PRINT """
<html>
<header>
  <title>thinBasic QOD #1</title>
</header>
<body>
<h1>Answer:</h1>
  <table border="0"  cellpadding="5">
    <tr><td>(1)</td><td>""" & ( 45 * ( 9 - 5 + 8 ) - 36 / 4 ) & """</td></tr>
    <tr><td>(2)</td><td>""" & ( 45 * ( 9 - ( 5 + 8 ) ) - 36 / 4 ) & """</td></tr>
    <tr><td>(3)</td><td>""" & ( 45 * ( 9 - 5 + 8 ) - ( 36 / 4 ) ) & """</td></tr>
    <tr><td>(4)</td><td>""" & ( 45 * ( ( 9 - 5 ) + 8 ) - 36 / 4 ) & """</td></tr>
  </table>  
</body>
</html>
"""

testnt.sb
IMPORT nt.bas

PRINT nt::RegRead("HKCU\\SOFTWARE\\SCRIPTBASIC\\DEBUGGER\\"),"\n"

C:\scriptbasic\test>scriba testnt.sb
sdbg

C:\scriptbasic\test>

ScriptBasic 2.2 (Windows 32) Attached
 

I added to the dbgcon (client remote debugger) the ability to pass the IP and port if not using the default.

' ScriptBasic Remote Console Debugger

cmdln = TRIM(COMMAND())
IF cmdln = "" THEN
  ' Default IP:Port
  OPEN "127.0.0.1:6647" FOR SOCKET AS #1
ELSE
  OPEN cmdln FOR SOCKET AS #1
END IF

WHILE NOT EOF(1)
  LINE INPUT #1, dbgs
  IF dbgs = ".\r\n" THEN
    PRINT "-> "
    LINE INPUT dbgc
    PRINT #1, dbgc
    IF CHOMP(dbgc) = "q" THEN GOTO Done
  ELSE
    dbgcmd = CHOMP(dbgs)
' l - List Source   
    IF LEFT(dbgcmd,13) = "Break-Point: " THEN
      IF MID(dbgcmd,14,1) = "0" THEN
        PRINT " "
      ELSE
        PRINT "*"
      END IF
      GOTO IT
    END IF
    IF LEFT(dbgcmd,13) = "Line-Number: " THEN
      PRINT FORMAT("%~[0000] ~",VAL(MID(dbgcmd,14)))
      GOTO IT
    END IF
    IF LEFT(dbgcmd,6) = "Line: " THEN
      PRINT MID(dbgcmd,7),"\n"
      GOTO IT
    END IF
' Unprocessed out
    PRINT dbgs
  END IF
IT:
WEND

Done:
PRINT #1,"q\n"
PRINT "Debug session closed.\n"

jrs@laptop:~/sb/test$ scriba dbgcon.sb 127.0.0.1:6666
Application: ScriptBasic Remote Debugger
Version: 1.0
Source-File-Count: 1
Source-File: dbgcontest.sb
Current-Line: 2
-> l -
 [0001] REM DBGLISTEN 127.0.0.1:6666
 [0002] a = 1
 [0003] b = "ScriptBasic"
 [0004] PRINT a,"\n"
 [0005] PRINT b,"\n"
Current-Line: 2
->

If you're running Ubuntu 64 bit and would like to try a beta of the ScriptBasic 2.2 release, see attached.

I wonder is ScriptBasic is the only 64 bit Basic interpreter at this point. 

scriba executable OK  
sbhttpd executable OK  
libscriba library OK  
MODULE sdbg:     dll OK   lib OK   bas OK  
MODULE hash:     dll OK   lib OK   bas OK  
MODULE curl:     dll OK   lib OK   bas OK  
MODULE re:       dll OK   lib OK   bas OK  
MODULE odbc:     dll OK   lib OK   bas OK  
MODULE sqlite:   dll OK   lib OK   bas OK  
MODULE curses:   dll OK   lib OK   bas OK  
MODULE mysql:    dll OK   lib OK   bas OK  
MODULE t:        dll OK   lib OK   bas OK  
MODULE gd:       dll OK   lib OK   bas OK  
MODULE cgi:      dll OK   lib OK   bas OK  
MODULE mt:       dll OK   lib OK   bas OK  
MODULE mxml:     dll OK   lib OK   bas OK  
MODULE ux:       dll OK   lib OK   bas OK  
MODULE trial:    dll OK   lib OK   bas OK  
MODULE zlib:     dll OK   lib OK   bas OK  
MODULE dbg:      dll OK   lib OK   bas OK  

ScriptBasic v2.2
Variation >>Ubuntu64<< build 1
Magic value 858994487
Node size is 24
Extension interface version is 11
Compilation: Dec 17 2012 11:30:13

ScriptBasic 2.2 BETA for Ubuntu 64 bit attached

Peter Verhas was kind enough to help solve my G global variable display issue. I still have a bit of cleanup to do but hope to release a beta for Linux and Windows this weekend.

Note: Displaying array element values with the ? or G will not be available in this release. (not implemented in the original code) A temporary workaround is to PRINT the array elements your interested in to the console from the debugged running program.

USE sdbg
a = 1
b = "ScriptBasic"
PRINT a,"\n"
PRINT b,"\n"

Console 1
jrs@laptop:~/sb/test$ scriba dbgcontest.sb
1
ScriptBasic
jrs@laptop:~/sb/test$

Console 2
jrs@laptop:~/sb/test$ scriba dbgcon.sb
Application: ScriptBasic Remote Debug Console
Version: 1.0
Source-File-Count: 1
Source-File: dbgcontest.sb
Current-Line: 1
-> s
Current-Line: 2
-> s
Current-Line: 3
-> G
Global-Variable-Name: main::a
Global-Variable-Value: 1
Global-Variable-Name: main::b
Global-Variable-Value: "ScriptBasic"
Current-Line: 3
-> l -
 [0001] a = 1
 [0002] b = "ScriptBasic"
 [0003] PRINT a,"\n"
 [0004] PRINT b,"\n"
Current-Line: 3
-> s
Current-Line: 4
-> s
Debug session closed.
jrs@laptop:~/sb/test$

The debugger support for ScriptBasic has been pretty much Windows centric with the original DBG internal preprocessor debugger. It was dependent on the Windows console screen API which left Linux without a debugger. One of Peter Verhas's last projects was a socket version of DBG and using a GUI client written in C++. (still a Windows solution) The socket debugger allowed remote debugging of the ScriptBasic multi-threaded web server. I didn't get around to testing the new debugger internal preprocessor until a couple years after Peter moved on.

I recently fixed a couple bugs with SDBG and wrote a console mode client for it in ScriptBasic under Linux. (which will also work in Windows) Here is a list of debugging features which mirror the old DBG debugger which documentation exists on this board.

• h help
  
• s step one line, or just press return on the line
  
• S step one line, do not step into functions or subs
  
• o step until getting out of the current function
    (if you stepped into but changed your mind)
  
• ? var  print the value of a variable
  
• u step one level up in the stack
  
• d step one level down in the stack (for variable printing)
  
• D step down in the stack to current execution depth
  
• G list all global variables
  
• L list all local variables
  
• l [n-m] list the source lines
  
• r [n] run to line n
  
• R [n] run to line n but do not stop in recursive function call
  
• b [n] set breakpoint on the line n or the current line
  
• B [n-m] remove breakpoints from lines
  
• q quit the program
  

Note:

• This is not an IDE but a console mode remote debugger.
• You can only display the executing scripts source, not change it.
• You can view the state of global and local variables but not alter them.
• If you set up the SB conf file for SDBG, you only need to insert USE SDBG in your source to use the debugger console with it. (no matter where the program is actually running)
  

I will be releasing both Windows32 and Ubuntu64 versions of the SDBG remote ScriptBasic debugger. I will also setup a CGI or SBHTTPD server example page that you can debug with the included DBGCON(.exe) standalone debugger. (source withheld until final release)

AIR must be busy with real life adventures and hasn't responded with a SB setup that will work with TDM-GCC-MinGW32/64. I used the interface.c from the MinGW-gcc version (SB 3.0) and replaced the VC10 one that was crashing. It seems there is something weird with the version of the mxml extension (Linux) I was trying get working. I will include the mxml VC10 version in the next build.

We gave it our best shot but Microsoft's Visual C/C++ is too unstable with ANSI/ISO C code. What works in one version of VC doesn't in another.

I'm going with Armando advice and stick with gcc across the board.

Here is the Mini-XML extension module example I have been trying to get working with VC10 now working when compiled with TDM-gcc-MinGW32.

C:\scriptbasic\test>scriba testmxml.sb
name = Belgian Waffles
price = $5.95
description = two of our famous Belgian Waffles with plenty of real maple syrup
calories = 650
name = Strawberry Belgian Waffles
price = $7.95
description = light Belgian waffles covered with strawberries and whipped cream
calories = 900
name = Berry-Berry Belgian Waffles
price = $8.95
description = light Belgian waffles covered with an assortment of fresh berries and whipped cream
calories = 900
name = French Toast
price = $4.50
description = thick slices made from our homemade sourdough bread
calories = 600
name = Homestyle Breakfast
price = $6.95
description = two eggs, bacon or sausage, toast, and our ever-popular hash browns
calories = 950

C:\scriptbasic\test>

Update

I have been working on the Windows version of the Mini-XML extension module that works fine under Linux and OSX. I was able to get  the module to compile with AIR's help but it would crash trying to load the XML file. I hit the wall and sent my effort over to Armando to debug As it turns out VC10 corrupts trying to load the tree but AIR was able to compile the same code with TDM-GCC-MinGW32 and it worked. (using the VC10 version of scriba)

Once we know what is causing VC10 to be transparently unhappy, we can send a bug report over to the Mini-XML maintainers.